Groupe 10
Code :
#include <Arduino.h>
constexpr int PIN_BUZZER = D3;
constexpr int PIN_BUTTON = D5;
constexpr int PRESSED_LEVEL = LOW; // niveau lu quand on appuie (étape 1)
constexpr unsigned long DEBOUNCE_MS = 30;
unsigned long debutBip = 0;
bool bipEnCours = false;
struct Button {
int pin;
int stableLevel; // dernier niveau confirmé
int lastRead; // dernière lecture brute
unsigned long lastChangeMs; // date du dernier mouvement du signal
};
Button button = {PIN_BUTTON, !PRESSED_LEVEL, !PRESSED_LEVEL, 0};
// Renvoie true une seule fois par appui, au moment où il est confirmé
bool justPressed(Button& b) {
int level = digitalRead(b.pin);
if (level != b.lastRead) { // le signal bouge : rebond ou vrai changement
b.lastRead = level;
b.lastChangeMs = millis();
}
if (millis() - b.lastChangeMs > DEBOUNCE_MS && level != b.stableLevel) {
b.stableLevel = level; // stable depuis 30 ms : changement confirmé
return level == PRESSED_LEVEL; // vrai sur l'appui, faux sur le relâchement
}
return false;
}
void bip(bool demarrer = false) {
if (demarrer && !bipEnCours) {
tone(PIN_BUZZER, 1000);
debutBip = millis();
bipEnCours = true;
}
if (bipEnCours && millis() - debutBip >= 100) {
noTone(PIN_BUZZER);
bipEnCours = false;
}
}
void setup() {
Serial.begin(115200);
pinMode(PIN_BUTTON, INPUT_PULLUP);
pinMode(PIN_BUZZER, OUTPUT);
}
void loop() {
static int count = 0;
if (justPressed(button)) {
count++;
Serial.printf("Appui n°%d\n", count);
bip(true);
}
bip();
}
2026-11-18 : sujet de la séance
Séance : planifiée · Durée : 1h30
Actions effectuées
Ce que j’ai réalisé pendant la séance.
Pourquoi
Les décisions prises et leurs raisons (mesures, essais, échanges avec l’équipe).
Idées pour la prochaine séance
Les prochaines actions, et ce qui bloque éventuellement.