2026-11-18 : TD2, bouton et joystick
Séance : planifiée · Durée : 1 h 30 Présents : Timothé Froumentin, Victor Fonte Nove Lamotte (toute la séance) Tutoriel suivi : Modules de la mallette (étapes 1 à 4)
Fait
- Étape 1 : module bouton câblé sur D5, lecture de son niveau au moniteur série. Le bouton lit LOW quand on appuie.
- Étape 2 : détection d’un appui unique avec anti-rebond de 30 ms : une seule ligne « Appui n°… » par appui, même bouton maintenu.
- Étape 3 : joystick câblé (X sur D0, Y sur D1, bouton du stick sur D2), lecture des valeurs brutes de 0 à 4095.
- Étape 4 : calibration du centre de l’axe X (≈ 1850 au repos) et normalisation entre -1.0 et +1.0. Le sens de l’axe est correct, pas besoin de l’inverser.
Comment ça marche
Le fichier include/config.h
Il regroupe tous les numéros de broches de la console au même endroit. Chaque programme fait #include "config.h" et utilise des noms (PIN_BUTTON, PIN_JOYSTICK_X…) au lieu de numéros. Si une broche change, on la modifie une seule fois.
| Constante | Broche | Module |
|---|---|---|
PIN_BUTTON | D5 | bouton |
PIN_JOYSTICK_X | D0 | joystick, axe X |
PIN_JOYSTICK_Y | D1 | joystick, axe Y |
PIN_JOYSTICK_SELECT | D2 | joystick, appui sur le stick |
Entrée numérique et résistance de tirage
Une broche en entrée numérique ne lit que deux états : HIGH (3,3 V) ou LOW (0 V). Sans rien de branché, elle « flotte » et lit n’importe quoi. Avec INPUT_PULLUP, l’ESP32-S3 active une résistance de tirage interne vers 3,3 V : la broche lit HIGH au repos et LOW quand le bouton la relie à la masse.
Les rebonds et l’anti-rebond
Un bouton mécanique rebondit : pendant quelques millisecondes, le contact s’ouvre et se ferme plusieurs fois. Sans précaution, un seul appui est compté plusieurs fois. La fonction justPressed() ne valide un changement que si le niveau reste stable pendant 30 ms, et ne renvoie true qu’au moment de l’appui, pas au relâchement. Elle utilise millis() (temps depuis le démarrage) plutôt que delay(), pour ne jamais bloquer le programme.
Le joystick et l’ADC
Le joystick contient deux potentiomètres (un par axe) : leur tension varie de 0 à 3,3 V selon la position du stick. L’ADC (convertisseur analogique-numérique) de l’ESP32-S3 transforme cette tension en nombre. Réglé sur 12 bits avec analogReadResolution(12), il donne une valeur de 0 à 4095.
Calibration et normalisation
- Calibration : au repos, le stick n’est pas exactement au milieu (2048). Au démarrage, on fait la moyenne de 16 lectures pour mesurer le vrai centre : chez nous ≈ 1850.
- Zone morte : au repos, la valeur tremble de quelques dizaines d’unités. Si l’écart au centre est inférieur à 300, on renvoie 0, pour qu’un objet ne bouge pas tout seul.
- Normalisation : on divise l’écart au centre par la course disponible de chaque côté (
centerd’un côté,4095 - centerde l’autre). Comme le centre n’est pas au milieu, chaque butée donne bien exactement -1.0 ou +1.0.
Comment on a fait
Étape 1 : lire le bouton
Câblage du module bouton (carte débranchée) :
| Module bouton | XIAO |
|---|---|
| S (signal, à gauche) | D5 |
| broche du milieu (VCC) | 3V3 |
| – (masse, à droite) | GND |
⚠️ Toujours 3V3, jamais 5V : les entrées de l’ESP32-S3 ne supportent pas plus de 3,3 V.
Programme de test : pinMode(PIN_BUTTON, INPUT_PULLUP) dans setup(), puis dans loop() un digitalRead() affiché en HIGH ou LOW toutes les 200 ms. Résultat : HIGH au repos, LOW à l’appui, d’où PRESSED_LEVEL = LOW.
Étape 2 : détecter un appui une seule fois
#include <Arduino.h>
#include "config.h"
const int PRESSED_LEVEL = LOW;
const unsigned long DEBOUNCE_MS = 30;
struct Button {
int pin;
int stableLevel;
int lastReading;
unsigned long lastChange;
};
Button button = {PIN_BUTTON, !PRESSED_LEVEL, !PRESSED_LEVEL, 0};
bool justPressed(Button &b) {
int reading = digitalRead(b.pin);
if (reading != b.lastReading) { // changement : on relance le chrono
b.lastReading = reading;
b.lastChange = millis();
}
if (millis() - b.lastChange > DEBOUNCE_MS && reading != b.stableLevel) {
b.stableLevel = reading; // stable depuis 30 ms : confirmé
return reading == PRESSED_LEVEL; // vrai seulement à l'appui
}
return false;
}
void setup() {
Serial.begin(115200);
pinMode(PIN_BUTTON, INPUT_PULLUP);
}
void loop() {
static int count = 0;
if (justPressed(button)) {
count++;
Serial.printf("Appui n°%d\n", count);
}
}
Test : chaque appui affiche une seule ligne, le compteur monte de 1 en 1, rien ne s’affiche en restant appuyé.
Étape 3 : lire le joystick
| Module joystick | XIAO |
|---|---|
| GND | GND |
VCC (marqué +5V) | 3V3 |
| VRx | D0 |
| VRy | D1 |
| SW | D2 |
void setup() {
Serial.begin(115200);
pinMode(PIN_JOYSTICK_SELECT, INPUT_PULLUP);
analogReadResolution(12); // 0 à 4095
}
void loop() {
int x = analogRead(PIN_JOYSTICK_X);
int y = analogRead(PIN_JOYSTICK_Y);
bool select = digitalRead(PIN_JOYSTICK_SELECT) == LOW;
Serial.printf("x=%d y=%d select=%d\n", x, y, select);
delay(100);
}
Test : au repos x et y sont proches du milieu, aux butées ils vont de ≈ 0 à ≈ 4095, select passe à 1 en enfonçant le stick.
Étape 4 : calibrer et normaliser l’axe X
const int JOYSTICK_DEADZONE = 300;
int joystickCenterX = 2048;
void calibrateJoystick() {
long sum = 0;
for (int i = 0; i < 16; i++) {
sum += analogRead(PIN_JOYSTICK_X);
delay(2);
}
joystickCenterX = sum / 16;
}
float normalizeJoystick(int raw, int center) {
int offset = raw - center;
if (abs(offset) < JOYSTICK_DEADZONE) return 0.0;
float course = (offset > 0) ? (4095 - center) : center;
return constrain(offset / course, -1.0, 1.0);
}
calibrateJoystick() est appelée à la fin de setup(), stick relâché. Dans loop(), on affiche normalizeJoystick(analogRead(PIN_JOYSTICK_X), joystickCenterX).
Test : centre mesuré ≈ 1850, 0.00 au repos, -1.00 et +1.00 aux butées, valeurs intermédiaires entre les deux, sens correct.
Pourquoi
config.hpour les broches : un seul endroit à modifier quand on passera de la breadboard à la carte soudée.INPUT_PULLUP: évite une entrée flottante, et ne gêne pas un module qui a déjà sa propre résistance.millis()plutôt quedelay(): dans le jeu, la carte devra lire le joystick, le bouton et mettre à jour l’écran en même temps ; undelay()bloquerait tout.- Calibrer au lieu de supposer 2048 : notre centre réel est ≈ 1850, avec 2048 supposé, la zone morte serait décalée de ≈ 200 et les butées ne donneraient pas exactement ±1.0.
- Zone morte de 300 : supprime les tremblements au repos. Effet de bord : en sortant de la zone morte, la valeur saute directement à environ ±0,15 au lieu de partir de 0.
- Difficulté rencontrée : repérer les broches du module bouton (marquées S, rien, –). Les schémas de câblage du tutoriel en ligne ont permis de s’en sortir.
Reste à faire
- Étape 5 : le buzzer, jouer une note.
- Étape 6 : l’écran, premier affichage.
- Étape 7 : les quatre modules ensemble (checkpoint TD2 : les quatre modules fonctionnent sur breadboard).
- Faire fonctionner TelePlot (reste du TD1).